CompileIt Names for ToolBox Access     CompileIt! 独自のもの
　Useful ToolBox Commands & Functions    よく使われるルーチン
　ToolBox Variables & Fields             よく使われる ToolBox 変数とフィールド
　High-Level File Manager                ファイルマネージャ
　HyperCard 2 Names and CallBacks        HyperCard 2.0 コールバック
　Color QuickDraw Commands & Functions   カラーＱＤルーチン
　Print Manager Commands & Functions     プリントマネージャ
　Custom Symbol Edit                     シンボル編集
　SuperCard Commands & CallBacks         SuperCard コールバック

　Mark Used Names   スクリプト中で使用しているものにマークする
　Add All           全てのシンボルを登録する
　Remove All        全てのシンボルを登録解除する
　Add Marked        マークされているシンボルを登録する
　Remove            マークされているシンボルを登録解除する
　Clear Marks       全てのマークを消す

-- CompileIt! script
function GetPixPattern thePt, width, height
  --
  if ( thePt is "?" ) or ( paramCount() = 0 ) then
    return "GetPixPattern( topLeft, width, height ) "
  end if
  if thePt is "!" then
    return "GetPixPattern 1.0"
  end if
  --
  put (item 1 of thePt) + 0 into L   -- 座標から left を取り出す
  put (item 2 of thePt) + 0 into T   -- 座標から top を取り出す
  put T + height - 1 into B          -- top に 高さを加えて bottom を作る
  put L + width - 1 into R           -- left に 幅を加えて right を作る
  --
  put "" into theResult
  --
  repeat with V = T to B
    repeat with H = L to R
      if GetPixel(H,V) is true then  -- ToolBox 関数
        put "1" after theResult
      else
        put "0" after theResult
      end if
    end repeat
    put return after theResult
  end repeat
  --
  delete last char of theResult
  return theResult
  --
end GetPixPattern

-- button script for GetPixPattern test stack
on mouseUp
  put "" into cd fld 1
  set the cursor to watch
  put GetPixPattern( "0,0", 32, 32 ) into cd fld 1
end mouseUp

-- CompileIt! script
function GetPixPattern2 thePt, width, height
  --
  if thePt is "!" then
    return "GetPixPattern 2.0"
  end if
  if ( thePt is "?" ) or ( thePt is "" ) then
    return "GetPixPattern2( topLeft, width, height ) "
  end if
  --
  put (item 1 of thePt) + 0 into L
  put (item 2 of thePt) + 0 into T
  put T + height - 1 into B
  put L + width - 1 into R
  --
  put NewHandleClear ( ( width + 1 ) * height ) into theResult -- 文字列を
  if ( ( MemErr <> 0 ) or ( theResult = nil ) ) then           -- 格納する
    return "Error : memory error "                             -- メモリを
  end if                                                       -- 準備する
  --
  put 1 into strIndex
  --
  repeat with V = T to B
    repeat with H = L to R
      if GetPixel(H,V) is true then
        put "1" into char strIndex of Handle theResult          -- "Handle"
      else                                                      -- に注目
        put "0" into char strIndex of Handle theResult
      end if
      add 1 to strIndex
    end repeat
    put return into char strIndex of Handle theResult
    add 1 to strIndex
  end repeat
  --
  put numToChar(0) into char strIndex - 1 of Handle theResult
  --
  return HyperCardText( theResult )
  --
end GetPixPattern2